Flashbattle.de - Flashforum / Webdesign Community & Developer`s Page

ActionScript-Quelltext

ActionScript-Quelltext

// example Audio Klasse
import djpublic.media.audio.Audio;
import mx.transitions.easing.*;
var song:String = "track.mp3";
var holder:MovieClip = Audio.createTarget (this, "__audioHolder", 1);
var globalEF:MovieClip = Audio.createTarget (this, "__globalEnterFrame", 2);
var audio:Audio = new Audio (holder);
audio.onProgress = function ():Void  {
    trace (this.percentLoaded);
};
audio.onLoadComplete = function ():Void  {
    trace ("*.mp3 ist fertig geladen");
};

audio.onFade = function ():Void  {
    trace ("fade start");
};
audio.onFadeComplete = function ():Void  {
    trace ("fade end...time= " + Math.round (getTimer () / 1000) + " sec");
};
audio.load (song, true);
audio.volume = 0;
audio.fadeVolume (50, None.easeNone, 10, true);
globalEF.onEnterFrame = function ():Void  {
    time_txt.text = audio.playTime + "/" + audio.totalTime;
    status_txt.text = audio.status;
    percentPlay_txt.text = Math.round (audio.percentPlayed) + "%";
    percentLoad_txt.text = Math.round (audio.percentLoaded) + "%";
    bytesLoad_txt.text = Math.round (audio.bytesLoaded);
    bytesTotal_txt.text = Math.round (audio.totalBytes);
};
play_btn.onRelease = function ():Void  {
    audio.play (0, 0);
};
pause_btn.onRelease = function ():Void  {
    if (audio.status == "PLAY") {
        audio.pause ();
    } else if (audio.status == "PAUSE") {
        audio.play (0, 0);
    }
};
stop_btn.onRelease = function ():Void  {
    audio.stop ();
};
ff_btn.onPress = function ():Void  {
    audio.fastWind (2000, true);
};
ff_btn.onRelease = ff_btn.onReleaseOutside = function ():Void {
    audio.stopFastWind ();
};
fr_btn.onPress = function ():Void  {
    audio.fastWind (2000, false);
};
fr_btn.onRelease = fr_btn.onReleaseOutside = function ():Void {
    audio.stopFastWind ();
};

ActionScript-Quelltext

ActionScript-Quelltext

import fresh.media.audio.*;

var track:String = "02.mp3"; // <---- hier Pfad zu einer mp3 eingeben

// Pufferungszeit setzen
Audio.bufferTime = 10;


var audio:Audio;
var controller:AudioController;
var mixer:AudioMixer;
var display:AudioDisplay;

var o:Object = {};
var seekPressed:Boolean = false;
var volPressed:Boolean = false;

// Audio
/*
* Audio(target:MovieClip)
*/
audio = new Audio(this);

// Audio Events
o.onLoadStart = function():Void{
    trace("Audio: onLoadStart");
    progress_mc._xscale = 0;
};
o.onLoadProgress = function(bytesLoaded:Number, totalBytes:Number, percentLoaded:Number):Void{
    trace("Audio: " + percentLoaded);
    progress_mc._xscale = percentLoaded;
};
o.onLoadFinish = function():Void{
    trace("Audio: onLoadFinish");
};

// Audioclip laden
/*
* getAudio(url:String, extern:Boolean, stream:Boolean):Void
*/
audio.getAudioClip(track, true);

// AudioController
/*
* AudioController(audio:Audio)
*/
controller = new AudioController(audio);

// AudioController Events
o.onAudioFinish = function():Void{
    trace("AudioController: onAudioFinish");
};

// AudioMixer
/*
* AudioMixer(audio:Audio)
*/
mixer = new AudioMixer(audio);
mixer.volume = 30;

// AudioDisplay
/*
* AudioDisplay(audioController:AudioController)
*/
display = new AudioDisplay(controller);


// addListener
audio.addListener(o);
controller.addListener(o);


// onEnterFrame Schleife 
onEnterFrame = function():Void{
    // display_txt
    display_txt.text = display.currentMinutes + ":" + display.currentSeconds + " / " + display.totalMinutes + ":" + display.totalSeconds;
    
    // seek
    if(seekPressed && bgSeek_mc._xmouse < bgSeek_mc._width && bgSeek_mc._xmouse > 0){
        seek_mc._width = bgSeek_mc._xmouse;
    }else if(!seekPressed){
        seek_mc._xscale = controller.percentPlayed;        
    }
    
    // volume
    if(volPressed && bgVolume_mc._xmouse < bgVolume_mc._width && bgVolume_mc._xmouse > 0){
        volume_mc._width = bgVolume_mc._xmouse;
        mixer.volume = volume_mc._xscale;
    }
};

// seek
seek_mc._xscale = 0;
bgSeek_mc.onPress = function():Void{
    if(controller.status == AudioController.PLAY){
        seekPressed = true;
    }
};
bgSeek_mc.onRelease = bgSeek_mc.onReleaseOutside = function():Void{
    if(controller.status == AudioController.PLAY){
        seekPressed = false;
        controller.percentSeek = seek_mc._xscale;
    }
};

// volume
volume_mc._xscale = mixer.volume;
bgVolume_mc.onPress = function():Void{
    volPressed = true;
};
bgVolume_mc.onRelease = bgVolume_mc.onReleaseOutside = function():Void{
    volPressed = false;
};


// play
play_btn.onRelease = function():Void{
    controller.play();
};

// pause
pause_btn.onRelease = function():Void{
    if(controller.status == AudioController.PLAY){
        controller.pause();
    }else if(controller.status == AudioController.PAUSE){
        controller.play();
    }
};

// stop
stop_btn.onRelease = function():Void{
    controller.stop();
};

// fForward
fForward_btn.onPress = function():Void{
    controller.fForward(1000);
};
fForward_btn.onRelease = fForward.onReleaseOutside = function():Void{
    controller.fStop();
};

// fRewind
fRewind_btn.onPress = function():Void{
    controller.fRewind(1000);
};
fRewind_btn.onRelease = fRewind_btn.onReleaseOutside = function():Void{
    controller.fStop();
};