Flashbattle.de - Flashforum / Webdesign Community & Developer`s Page

ActionScript-Quelltext

class djpublic.utils.ToolTip
{
    private static var DEFAULT_DEPTH         : Number         = 12432; //*#pn Wert willkürlich gewählt. Sollte aber hoch sein.
    private static var DEFAULT_TIMELINE    : MovieClip     = _root;
    
    private var activated    : Boolean = true;
    
    
    /*
    * PROPERTIES
    *    bgColor:Number [read, write] = 0xffffcc
    *    borderColor:Number [read, write] = 0x000000
    *    textColor:Number [read, write] = 0x000000
    *    font:String [read, write] = "Verdana"
    *    fontSize:Number [read, write] = 10
    *    embededFont:Boolean [read, write] = false
    *    time:Number [read, write] = 500
    *
    * METHODES
    *    shortcut (obj:Object, timeline:MovieClip, depth:Number, str:String):Void
    *    create (timeline:MovieClip, depth:Number, str:String):Void
    *    destroy ():Void
    *    
    *    
    */
    private var _mc            : MovieClip;
    private var _tf            : TextField;
    private var _format        : TextFormat;
    private var _id            : Number;
    //
    private var _bgColor        : Number = 0xBFE3EE;
    private var _borderColor    : Number = 0x003366;
    private var _textColor        : Number = 0x000000;
    private var _font            : String = "Verdana";
    private var _fontSize        : Number = 10;
    private var _time            : Number = 500;
    private var _embededFont    : Boolean = false;
    /*
     *    PROPERTIES
     */
    // bgColor
    public function set bgColor(value : Number) : Void
    {
        this._bgColor = value;
    }
    public function get bgColor() : Number
    {
        return this._bgColor;
    }
    // textColor
    public function set textColor(value : Number) : Void
    {
        this._textColor = value;
    }
    public function get textColor() : Number
    {
        return this._textColor;
    }
    // font
    public function set font(value : String) : Void
    {
        this._font = value;
    }
    public function get font() : String
    {
        return this._font;
    }
    // fontSize
    public function set fontSize(value : Number) : Void
    {
        this._fontSize = value;
    }
    public function get fontSize() : Number
    {
        return this._fontSize;
    }
    // borderColor
    public function set borderColor(value : Number) : Void
    {
        this._borderColor = value;
    }
    public function get borderColor() : Number
    {
        return this._borderColor;
    }
    // time
    public function set time(value : Number) : Void
    {
        this._time = value;
    }
    public function get time() : Number
    {
        return this._time;
    }
    // embededFont
    public function set embededFont(value : Boolean) : Void
    {
        this._embededFont = value;
    }
    public function get embededFont() : Boolean
    {
        return this._embededFont;
    }
    
    function ToolTip()
    {
    }
    /*
        *    shortcut (obj:Object, timeline:MovieClip, depth:Number, str:String):Void
        */
    public function shortcut(obj : Object, msg : String, timeline : MovieClip, depth : Number):Void
    {
        var tt:ToolTip = this;
        
        obj.onRollOver = function():Void 
        {
            if (tt.isActivated()) //*#pn
                tt.create(msg, timeline, depth);
        };
        obj.onRollOut = obj.onDragOut = function ():Void
        {
            tt.destroy();
        };
        
        //Mouse.addListener(obj);
    }
    /*
     *    create (timeline:MovieClip, depth:Number, str:String):Void
     */
    public function create(msg : String, timeline : MovieClip, depth : Number) : Void
    {//*#pn
        if (timeline == null)     timeline = DEFAULT_TIMELINE;
        if (depth == null)        depth     = DEFAULT_DEPTH;
        
        this._id = setInterval(this, "show", this.time, msg, timeline, depth); //*#pn
    }
    private function show (msg : String, timeline : MovieClip, depth : Number) : Void
    {
        this.drawTip(msg, timeline, depth);
        this._mc.onMouseMove = function():Void 
        {
                this._x = timeline._xmouse + 5;
                this._y = timeline._ymouse + 25; //- this._height;
                
                updateAfterEvent(); //*#pn "flüssigere" Bewegung
        };
        
        clearTimeOut(this._id);
    }
    
    
    /*
     *    create (timeline:MovieClip, depth:Number, str:String):Void
     */
    private function drawTip(msg : String, timeline : MovieClip, depth : Number) : Void
    {
        /* Falls diese Methode nicht nur von create() aufgerufen wird, if-Anweisungen nicht auskommentieren!
        if (timeline == null)     timeline = DEFAULT_TIMELINE;
        if (depth == null)        depth     = DEFAULT_DEPTH;
        */
        
        this._format                 = new TextFormat();
        this._format.font             = this.font;
        this._format.size             = this.fontSize;
        
        this._mc = timeline.createEmptyMovieClip("__ToolTipMovieClip", depth);
        this._mc.createTextField("__ToolTipTextField", depth, 0, 0, 10, 10);
        this._tf                     = this._mc["__ToolTipTextField"]; //*#pn
        this._tf.autoSize             = true;
        this._tf.border             = true;
        this._tf.borderColor         = this.borderColor;
        this._tf.background         = true;
        this._tf.backgroundColor     = this.bgColor;
        this._tf.selectable         = false;
        this._tf.embedFonts         = this.embededFont;
        this._tf.text                 = msg;
        this._tf.setTextFormat(this._format);
        //
        this._mc._x = timeline._xmouse;
        this._mc._y = timeline._ymouse + 25; //- this._height;
    }
    /*
     *    destroy():Void
     */
    public function destroy() : Void
    {
        this.clearTimeOut (this._id);
        this._mc.removeMovieClip();
        this._tf.removeTextField();
        delete this._mc.onMouseMove;
    }
    //*#pn
    public function isActivated () : Boolean
    {
        return activated;
    }
    //*#pn
    public function activate () : Void
    {
        activated = true;
    }
    //*#pn
    public function deactivate () : Void
    {
        activated = false;
    }
    
    /*
    *    setTimeOut (func:Function, time:Number):Void
     */
    /*private function setTimeOut (func:Function, time:Number):Number {
            var args:Array = arguments.splice (2);
            function f () {
                clearInterval (id);
                func.apply (null, args);
            }
            var id:Number = setInterval (f, time);
            return id;
     }*/
     
    /*
     *    clearTimeOut (id:Number):Void 
     */
    private function clearTimeOut (id : Number) : Void
    {
        clearInterval(id);
    }

}